Happy? Unhappy? The Choice is yours... "변화의 시기에는 배우려고 하는 이들이 세상을 차지합니다"

/**
 * @version 0.1
 * @author lovedev
 */
package net.asjs{
 
 /**
  * 사용방법
  * EventManager.addEvent
  * "이벤트가 할당될 객체","이벤트 타입","리스너","전달할 인자값...N"
  */
 
    import flash.events.Event;
    import flash.events.IEventDispatcher;  
    import flash.utils.Dictionary;
 
    public class EventManager {
 
  private static var eventList:Dictionary = new Dictionary();
 
  /**
   * 오브젝트에 이벤트 추가하기
   * @param target
   * @param eventType
   * @param listener
   * @param ...rest
   */
  public static function addEvent (
   targetIED:IEventDispatcher,
   eventType:String,
   listener:Function,
   ...rest ) : void {
   
   if (!eventList[targetIED]) eventList[targetIED] = new Object();
            eventList[targetIED][eventType] = new Object();
   eventList[targetIED][eventType].listener = listener;
   eventList[targetIED][eventType].args = rest;
            targetIED.addEventListener(eventType, onDispatchEvent);                       
        }
       
  /**
         * 이벤트 할당자
         * @param evt
         */
        private static function onDispatchEvent(evt:Event):void {  
            var targetIED:IEventDispatcher = evt.currentTarget as IEventDispatcher;           
   var eventType:String = evt.type;
           
   var listener:Function = eventList[targetIED][eventType].listener;
            var args:Array = eventList[targetIED][eventType].args;           
            if(!(args[0] is Event))args.unshift(evt);
            listener.apply(targetIED, args);  
   
        }
 
        /**
         * 이벤트 삭제
         * @param target
         * @param eventType
         */
        public static function removeEvent (
   targetIED:IEventDispatcher, eventType:String ) : void {  
   
   eventList[targetIED][eventType] = null;
            targetIED.removeEventListener(eventType, onDispatchEvent);
        }    
       
    }
}