lovedev

가끔 이벤트 핸들러에 인자 값을 전달한다던지, 특정 횟수 만큼 호출되고 나면, 삭제를 해야 한다던지 할 경우가 있지요..
그런 이유로 다들 EventUtil 하나 정도는 가지고 계실 것 같은데요 ^^;

잉여 돋는 시간에 프레임워크를 만들고 있는데, 그 중 일부인 소스 공유합니다.
사용 방법은 주석에 써놨습니다~ ^^

다들 즐거운 하루 되세용~

package actionwire.util
{
	
import flash.events.Event;
import flash.events.IEventDispatcher;
import flash.utils.Dictionary;

/**
 * 
 * @author lovedev
 * @example 사용 예
 *  
 *  var sp:Sprite = new Sprite();
 *  EventProxy.addEventListener(sp, Event.SELECT_ALL, function($e:Event, $test:String):void
 *  {
 *	trace($test);
 *  },1,"testMessage AAA");
 *	
 *  var fn:Function = function($e:Event, $test:String):void
 *	{
 *		trace($test);
 *	};
 * 	
 *	EventProxy.addEventListener(sp, Event.SELECT_ALL, fn,0,"TestMessage BBB");
 *	
 *	sp.dispatchEvent(new Event(Event.SELECT_ALL));
 *	EventProxy.removeEventListener(sp, Event.SELECT_ALL, fn);
 *	sp.dispatchEvent(new Event(Event.SELECT_ALL));
 * 
 * //output
 * //testMessage AAA 
 * //TestMessage BBB
 * 
 * -----------------------------------------------------------------------------------
 * //이벤트 dispatch는 2번 되었지만
 * //테스트 메시지 AAA를 찍는 핸들러는 1회 호출 후 자동 remove 되었으며, 
 * //테스트 메시지 BBB를 찍는 핸들러는 강제 remove되어 핸들러가 호출되지 않는다.
 * -----------------------------------------------------------------------------------
 * 
 * 
 */	
public class EventProxy
{
	
	private static var _eventList:Dictionary = new Dictionary();
	
	/**
	 * 이벤트 발생이 가능한 객체에 이벤트를 등록합니다.
	 * @param $target 이벤트 발생 객체
	 * @param $eventType 이벤트 타입
	 * @param $listener 이벤트 핸들러
	 * @param $limitCount 
	 * 
호출 제한 카운트 지정 0일 경우 무제한 지정되었을 경우, 
	 * 지정된 수만큼 반복후 remove 
	 * @param $rest 핸들러에 전달될 인자
	 * 
	 */			
	public static function addEventListener(	$target:IEventDispatcher,
												$eventType:String,
												$listener:Function,
												$limitCount:uint = 0,
												...$rest):void
	{
		if(!_eventList[$target])
			_eventList[$target] = {};
		
		if(!_eventList[$target][$eventType])
			_eventList[$target][$eventType] = [];
		
		_eventList[$target][$eventType].push({
			"listener" : $listener,
			"args" : $rest,
			"limitCount" : $limitCount,
			"executeCount" : 0
		});

		if(_eventList[$target][$eventType].length == 1)
		     $target.addEventListener($eventType, onProxyDispatchEvent);
	}
	
	/**
	 * 
	 * @param $e
	 * 
	 */		
	private static function onProxyDispatchEvent($e:Event):void
	{
		var target:IEventDispatcher = $e.currentTarget as IEventDispatcher;            
		var eventType:String = $e.type;	
		
		if(_eventList[target].hasOwnProperty(eventType) &&
			_eventList[target][eventType].length > 0)
		{
			var listener:Function, args:Array, 
				limitCount:uint, idx:String, eventInfo:Object;
			
			var removableListener:Array = [];
			
			for(idx in _eventList[target][eventType]) 
			{
				eventInfo = _eventList[target][eventType][idx];
				listener = eventInfo.listener;
				args = eventInfo.args;
				
				if(!(args[0] is Event)) args.unshift($e);
				listener.apply(target, args);
				
				eventInfo.executeCount++;
				
				if(eventInfo.limitCount > 0 
						&& eventInfo.limitCount <= eventInfo.executeCount)
				{
					removableListener.push(eventInfo);
				}
			}
			
			for each (eventInfo in removableListener)
				removeEventListener(target, eventType, eventInfo.listener);
			
			listener = null;
			args = null;
			idx = null;
			eventInfo = null;
			removableListener = null;
		}
	}
	
	/**
	 * EventProxy를 통해 생성된 이벤트를 제거합니다.
	 * @param $target
	 * @param $eventType
	 * @param $listener
	 * 
	 */		
	public static function removeEventListener(	$target:IEventDispatcher, 
											   		$eventType:String = null,
													$listener:Function = null):void
	{
		//Case 1
		if($eventType === null && $listener === null)
		{
			for(var eventType:String in _eventList[$target])
			{
				$target.removeEventListener(eventType, 
						onProxyDispatchEvent);
			}
			
			delete _eventList[$target];
			return;
		}
		
		//Case 2
		if($eventType !== null && $listener === null 
				&& _eventList[$target].hasOwnProperty($eventType))
		{
			$target.removeEventListener($eventType, 
					onProxyDispatchEvent);
			delete _eventList[$target][$eventType];
			return;
		}
		
		//Case 3
		if($eventType !== null && $listener !== null 
				&& _eventList[$target].hasOwnProperty($eventType))
		{
			for(var idx:String in _eventList[$target][$eventType])
			{
				if(_eventList[$target][$eventType][idx].listener === $listener)
				{
					_eventList[$target][$eventType][idx] = null;
					_eventList[$target][$eventType].splice(int(idx), 1);						
					break;
				}					
			}
			
			if(_eventList[$target][$eventType].length == 0)
			{
				$target.removeEventListener($eventType, 
						onProxyDispatchEvent);
				delete _eventList[$target][$eventType];
			}
		}
	}
	
}
}